I just realized today, quite belatedly, that you can control GeekTool on your Mac with AppleScript. I just wanted to play around with it a bit, so I threw together a countdown timer. This could be done much more elegantly, I’m sure; I just wanted to see what I could pull off quickly.

The script takes an argument ending in an integer (interpreted as minutes), or a colon-separated hour/minutes argument. The last argument is always the time from now. For example Pick up the kids 1:30 would set a timer for an hour and 30 minutes from now. Feed the fish 10 would set a timer to go off in 10 minutes.

The script calculates the target time and then runs a loop every second to update a GeekTool shell geeklet with the countdown timer. Yes, you could probably do this more efficiently by making use of the Geeklet’s interval property, but… meh, I don’t have an excuse. I kind of thought of that after writing the script. It’s Sunday, lay off.

If you want to play with it, you need to have GeekTool installed and running. Create a Shell Geeklet by dragging the shell icon to your desktop from the GeekTool window. In the properties for the geeklet, name it “GeekTimer” and leave the timeout and refresh values at zero. Size it so that it’s the full width of your screen, set the paragraph justification to centered, pick a font/color and make it as large as you want.

Now, save the AppleScript below as a file called geektooltimer somewhere on your drive. Wherever you put it, you’ll need to adjust any commands that call it to match your own path.

The AppleScript

#!/usr/bin/osascript

on padNum(_num)
    if _num < 10 then set _num to "0" & _num
    return _num
end padNum

on run argv
    set message to item 1 of argv

    tell application "GeekTool Helper" to set command of shell geeklet named "GeekTimer" to "echo"

    set {astid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, " "}
    set _task to text items 1 thru ((count of text items of message) - 1) of message as string
    set _min to last item of text items of message
    if (offset of ":" in _min) > 0 then
        set AppleScript's text item delimiters to ":"
        set _min to (item 1 of text items of _min) * 60 + (item 2 of text items of _min)
    end if
    set AppleScript's text item delimiters to astid

    set _date to current date
    set _target to (_date + (_min * 60))
    repeat
        set timeLeft to (_target - (current date))
        set minLeft to round timeLeft / 60 rounding down
        if minLeft > 60 then
            set minLeft to (round minLeft / 60 rounding down) & ":" & padNum(minLeft mod 60)
        else
            set minLeft to padNum(minLeft)
        end if
        set secLeft to padNum(timeLeft mod 60)
        tell application "GeekTool Helper"
            set command of shell geeklet named "GeekTimer" to "echo \"" & _task & " in " & minLeft & ":" & secLeft & "\""

            if (current date) ≥ _target then
                do shell script "/usr/bin/afplay /System/Library/Sounds/Glass.aiff"
                set command of shell geeklet named "GeekTimer" to "echo \"Time to " & _task & "\""
                return "Time to " & _task
            end if
        end tell
        delay 1
    end repeat
end run

Note that the hashbang at the beginning will let you make it executable and call it without osascript, but I used osascript in the methods below just to be safe.

When the timer is up, it will use afplay to ring a bell and set the final text of the Geeklet to your reminder title. I’m pretty sure afplay is included in a standard install, but if you run into issues just remove that line or substitute your own alert method.

As a Bash function

I’m mostly calling this script from the command line. I added a function to ~/.bash_profile that looks like this:

## GeekTool Timer
# `gtt Pick up the kids 1:30` sets a timer for 1 hour and 30 minutes
# `gtt Feed the fish 10` will set a timer for 10 minutes
# Running `gtt` with no arguments will clear the running timer and exit
gtt() {
    # if a timer is running, kill it
    pid=$(ps ax | grep -E "osascript .*/geektooltimer" | grep -v grep | awk '{print $1}')
    [[ $pid ]] && kill $pid
    # Clear any existing text
    /usr/bin/osascript -e 'tell application "GeekTool Helper" to set command of shell geeklet named "GeekTimer" to "echo"'
    # if there are arguments, run the script with them. 
    if [[ $# -gt 0 ]]; then
        /usr/bin/osascript ~/scripts/geektooltimer "$*" 2>&1 &
    fi
}

Drop that into your ~/.bash_profile and run source ~/.bash_profile. Now, in combination with the previous AppleScript, you have a gtt command for setting timers on your desktop from Terminal. Be sure to modify the path in the last command (the one that calls geektooltimer) to match the location of the AppleScript you created.

The function first checks to see if a timer is already running, and if so, kills it. Then it clears any text currently in the “GeekTimer” Geeklet, and then runs the AppleScript and passes all command line arguments as one quoted string. The geektoolreminder script handles parsing out the last number and turns the preceding text into the reminder title. Running just gtt without any arguments will clear the current timer.

There’s not a lot of error checking involved, so incorrect parameters will throw errors on the command line. Feel free to spiff it up.

As a Launchbar (or Alfred or whatever) action

You can also call the script from Launchbar by creating an action like:

on handle_string(message)
    do shell script "/Users/ttscoff/scripts/geektooltimer '" & message & "' &"
end handle_string

Name the action “GeekTool Reminder” (save it in ~/Library/Application Support/Launchbar/Actions/GeekTool Reminder.scpt). You’ll call it up by popping up Launchbar and typing “GTR” or similar, then pressing space. Enter the text of the reminder and end it with a minute or hour:minute designation. Minor catch: execute it with Option-Return to run it in the background, otherwise Launchbar will freeze until the timer is up.

In Alfred you can probably make a straight shell script that runs in the background automatically, so it would be more in line with the Bash function above than with the Launchbar AppleScript method.

What I’m hoping is that this example will get a ball rolling, and someone will see a little bit more exciting potential in it than I came up with on a lazy Sunday. Got a cool AppleScript (or even an idea) for GeekTool? I’d love to hear about it!

Related posts:

1. Geeklet: 1-minute average CPU load
2. ImageMagick and GeekTool (or NerdTool)
3. Geeklets: weather and forecast

Originally posted on BrettTerpstra.com at Desktop countdown timer with GeekTool and AppleScript

I wrote a while back about some Day One geekery, and shared the git wrapper I set up for bagging some of my larger commit messages to Day One entries automatically. Then Rob went and asked me if I could do something similar with TaskPaper, logging archived tasks to Day One on the fly. Had to try it.

I built the script using the newer query syntax, and I find it a little more stable than the old project-by-project parsing method (nice work, Jesse). To use it, you just need a TaskPaper document with at least one project and an “Archive:” section, and Day One with the CLI tool installed.

• Using the frontmost document in TaskPaper, it grabs all the @done tasks¹ (with or without a date) that aren’t already in the “Archive” project for processing.
• It goes through a few of my common “in-process” tags (@na, @priority, @waiting) and removes them if they exist on a @done task (they’re meaningless after completion).
• Then it looks to see if there’s a @project tag, and if not, it adds one for the project the task was in when it was archived (I think this is default TaskPaper behavior…).
• The full text content of each task (complete with Markdown-style list delimiter and all of the project/date tags you’d want in a log entry) is added to a string.
• Each @done task is then moved to the “Archive” project.
• The name of the parent file and the list of all the tasks you just archived are sent as a single entry to Day One using the dayone CLI tool.

I’m not certain that the end results of using this are superior to logging commit messages. With commit messages I’m talking about what I just did and noting any issues; just being more verbose in general. This technique is a really convenient way to log, though, if you’re already a TaskPaper (and Day One) user, and works perfectly as a supplement to other logging methods.

As you archive your tasks, they get dropped into a calendar view in ready-to-display Markdown format. It’s faster and prettier than to trying to maintain and sort archives of finished tasks in TaskPaper. Given that this is pretty much automatic in my current workflow, I’m just going to let both logging systems churn for a while and see if one or the other isn’t pulling its weight.

The script is thoroughly commented. Probably unnecessarily so for such a short task (I’m pretty sure there’s more comment than code in there). See below for brief installation instructions, and click here to open it directly in AppleScript Editor.

set archivedTasks to ""
tell application "TaskPaper"
	tell front document
		-- don't care which file your log entry came from?
		-- comment the next line out
		set archivedTasks to "## " & name & return
		repeat with _task in search with query "project != Archive and @done"
			if entry type of _task is not project type then
				-- remove common tags that won't matter after archiving
				repeat with _tag in {"na", "next", "priority", "waiting"}
					if exists (tag named _tag of _task) then delete tag named _tag of _task
				end repeat
				-- if there's no project tag on the task, 
				-- add the task's current project as a tag
				if not (exists (tag named "project" of _task)) then
					tell _task to make tag with properties {name:"project", value:(name of containing project of _task as rich text)}
				end if
				-- append the full text of the entry, including tags, to our log
				set archivedTasks to archivedTasks & (text line of _task)
				-- archive it
				move entry id (id of _task) to beginning of entries of project "Archive"
			end if
		end repeat
	end tell
end tell
-- send the accumulated results to Day One via the command line tool
-- http://dayoneapp.com/faq/#commandlineinterface
-- You'll need to run `ln -s "/Applications/Day One/Day One.app/Contents/MacOS/dayone" /usr/local/bin/dayone` to have it accessible at this path
do shell script "echo " & (quoted form of archivedTasks) & "|tr -d \"\\t\"|/usr/local/bin/dayone new"

Just copy the script into AppleScript Editor (or click the handy link) and save it as a compiled script in ~/Library/Scripts/Applications/TaskPaper (creating the folder if it’s not there). If you have the AppleScript menubar item enabled in AppleScript Editor preferences, you’ll be able to access the script from within TaskPaper. It’s really only convenient if you have a hotkey, though. Keyboard Maestro, FastScripts, Launchbar, System Preferences… whatever your poison, just make it easy.

Again, you’ll need to have the dayone CLI tool linked to /usr/local/bin/dayone (or modify the path in the script). If you have Day One installed in the standard /Applications directory, just run this in Terminal:

ln -s "/Applications/Day One/Day One.app/Contents/MacOS/dayone" /usr/local/bin/dayone

Thanks for the idea, Rob!

Related posts:

1. Automating TaskPaper to Day One logs
2. A few scripts for TaskPaper users
3. Totally TaskPaper

Originally posted on BrettTerpstra.com at Log TaskPaper archives to Day One

As of recent versions, Notational Velocity and nvALT have a URL handler for nv:// (or nvalt://). Using the /find/ parameter allows you to initiate a search in NV from a link, e.g. nv://find/abnote%3AJohnny Appleseed. If you use a unique prefix and full name, you can pinpoint a single note without having to create a file or locate the note’s ID. The first time you click the link, it will open a search in NV, and pressing Return will create the note and begin editing. Once the note is there, it will locate it instantly the next time you click the link.

I’m using the prefix “abnote:” on my notes. This AppleScript will create the URL entry automatically from the selected entries’ first and last names, and you can edit the prefix in the script to be anything you like. Just save it as “Add NV Note.scpt” in ~/Library/Scripts/Applications/Address Book and it will show up in your script menu² when you’re in Address Book. You can run it on a bunch of entries (it’s not optimized to run on an entire large address book, though), or one at a time as you need it.

I wrote this on Lion. I honestly have no idea if it works on anything earlier. It might³.

The script

tell application "Address Book"
	set thePeople to the selection
	repeat with thisPerson in thePeople
		set theName to name of thisPerson as string
		make new url at end of urls of thisPerson with properties {label:"NV Note", value:"nv://find/abnote%3A" & theName}
	end repeat
	save
end tell

Related posts:

1. Address Book search and Skype from the command line
2. nvALT 2.1 in the wild
3. nvALT 1.0.8 progress

Originally posted on BrettTerpstra.com at Connecting nvALT and Address Book

It’s designed to work with promo code giveaways. So far, that’s what my giveaways have been. If I end up running a giveaway with a different registration method, I’ll extend the script and post an update for anyone interested.

This method currently has two requirements/limitations based on my own needs and setup. First, it only works with Mail.app for collecting entries and sending notifications. Second, the regular expressions it uses to find the entrants name, email and IP address are based on the standard WordPress comment notification emails. The basic idea here could easily be applied to other AppleScript-able email applications and modified to parse any format, but I’ll leave that up to intrepid readers for now.

How it works

First, I do a search for the subject line in Mail. All of the comment notifications that WordPress sends me for the post have the same subject line, so that gathers them all very quickly. All that matters is that I can select them all before running the script.

Next, I run the AppleScript. It begins by asking me for the giveaway app’s name and requests my list of promo codes. Then the script pulls the names and the message content from each selected email, passing the information to a Ruby script which scans the content for the actual email address (necessary because the actual sender on the email is always my WordPress address) and entrant’s name/handle and IP. The list of results are then passed to a second Ruby script along with the promo codes. This script checks for duplicates in the emails and IPs, picks enough random numbers (range 0 — number of entrants) to match each code provided (recursive function to avoid duplicate numbers). The Ruby script then opens a new message in Mail.app for each winner, and populates it with recipient, subject, congratulatory message (including code) and signature. It also adds the mailto: link with all of this info to an HTML file on the Desktop for reference.

It needs some improvements, especially in the mail creation routine. It currently uses the mailto AppleScript command, but really should create the outgoing message step by step, which would ultimately allow for complete automation at some point. For the time being I still want to be able to confirm the winners and message content anyway; I’ll automate more when I have full trust in it.

The AppleScript

(* 
PickWinners by Brett Terpstra, 2011, freely distributed
Picks random winners from selected WordPress comment notification emails in Mail.app
Checks for duplicate emails and IP addresses
On run, requests Application title and a newline-separated list of promo codes
Picks winners from list for each promo code and opens ready-to-send notification emails in Mail.app
Saves list of winners in HTML file with mailto links (including message and promo code)
*)
 
set pickWinnerScript to (path to me) & "Contents:Resources:Scripts:pickwinners.rb" as string
set extractEmailScript to (path to me) & "Contents:Resources:Scripts:extractemail.rb" as string
property winners : ""
set _res to display dialog "Application name?" default answer ""
set appname to text returned of _res
set _res to display dialog "Enter promo codes" default answer "Paste codes, one per line"
set codes to text returned of _res
 
tell application "Mail"
	set _sel to the selection
	set entries to {}
 
	repeat with _msg in _sel
		set nameAndEmail to do shell script "\"" & (POSIX path of extractEmailScript) & "\" \"" & content of _msg & "\""
		set end of entries to nameAndEmail
	end repeat
 
	set {astid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "
"}
	set emails to entries as string
	set AppleScript's text item delimiters to astid
 
	set winners to do shell script "\"" & (POSIX path of pickWinnerScript) & "\"  \"" & appname & "\" \"" & codes & "\" \"" & emails & "\""
end tell
 
if winners is "error" then
	display dialog "There was an error generating winners"
else
	set _btn to display dialog "Winners written to " & winners buttons {"OK", "Open in Safari"}
	if button returned of _btn is "Open in Safari" then
		tell application "Safari" to open (POSIX file winners) as alias
	end if
end if

extractemail.rb

#!/usr/bin/env ruby
 
input = ARGV.join(" ")
emailmatch = input.match(/E-mail : (.*)/)
namematch = input.match(/Author : (.*?) \(IP: (.*?)\)/)
 
print "#{namematch[1].strip} <#{emailmatch[1].strip}> (#{namematch[2].strip})"

pickwinners.rb

#!/usr/bin/env ruby
require 'ftools'
 
appname = ARGV[0]
ARGV.shift
codes = ARGV[0].split
count = codes.length
ARGV.shift
input = ARGV[0].split("\n").uniq
 
norepeat_email = []
norepeat_IP = []
entries = []
 
input.each {|entry|
  name,email,ip = entry.scan(/^(.*?) *<([^ ]+)> \((.*?)\)/)[0]
  unless (norepeat_email.include?(email) || norepeat_IP.include?(ip))
    norepeat_email.push(email)
    norepeat_IP.push(ip)
    entries << { 'name' => name, 'email' => email }
  end
}
 
def pick_number(max,numbers)
  num = rand(max)
  if numbers.include? num
    pick_number(max,numbers)
  else
    return num
  end
end
 
randoms = []
count.times do
  randoms.push(pick_number(entries.length,randoms))
end
 
winners = []
randoms.each_with_index {|winner,i|
  entry = entries[winner]
  name = entry['name']
  email = entry['email']
  mailto = %Q{mailto:#{email}?subject=Congratulations #{name}, you won!&body=Here is your promo code for #{appname}: #{codes[i]}%0A%0AThanks for reading!%0A%0A-Brett}
  link = %Q{<li><a href="#{mailto}">#{name} <#{email}></a></li>}
  winners.push(link)
  %x{echo 'tell application "Mail" to mailto "#{mailto.gsub(/'/,"\'")}"'|osascript}
}
 
if winners.length == count
  output = "<ul>"
  output += winners.join("\n")
  output += "</ul>"
 
  outfile = File.new(File.expand_path("~/Desktop/#{appname}Winners.html"),'w+')
  outfile.puts output
  outfile.close
  puts File.expand_path("~/Desktop/#{appname}Winners.html")
else
  puts "error"
end

It’s not the most elegant solution, but it does the job of ensuring randomness and handling the nitty gritty parts of running a contest.

Related posts:

1. Listary giveaway, get yours!
2. Five Yoink promo codes up for grabs!
3. iOS App Giveaway: WriteUp

Originally posted on BrettTerpstra.com at Automating random giveaways, v1.0

I bought a MacBook Air recently. I have never been this happy with an Apple hardware purchase before. Not to gush, but I’ve bought and loved a lot of Macs and this one takes the cake. I’m doing more and more of my everyday work and writing on it, but I still like to sit down at the dual-monitor setup of my Mac Pro fairly regularly. When I do that, the Air becomes an auxiliary machine and I offload most of my chat and social apps to it. The annoying side of this setup is that I end up with Safari tabs piling up on both Macs, and half of them really make more sense on the other machine.

I wrote a pair of scripts that execute over SSH to pull in all of the browser tabs from the front window of Safari on the other Mac into new tabs on the one calling the script. They’re designed to run on Macs on the same network, though they’d work remotely if you could think of a reason to do it. I run it in both directions, and call it with a simple do shell script AppleScript in ~/Library/Scripts/Applications/Safari so it’s in my menubar when I’m browsing.

Just a few prerequisites:

1. You need keyless ssh set up between the two (or more) Macs. If you want a two-way sync, you need keys in both directions. This article has everything you need.
2. To keep things simple, set up a ~/.ssh/config file on each machine you want to pull tabs to. Create the file if you don’t have one, or add this at the bottom of an existing one, modifying it for your setup:

host air
  HostName computername.local
  User remoteusername

Now you can just install the scripts, edit one line on each and start pulling tabs back and forth between computers.

remotetabs.rb

This goes on the machine you want to pull from. If you’re going both directions, you’ll want both scripts on both machines. Easy enough, right? Save this one as remotetabs.rb in ~/scripts/ and run chmod a+x ~/scripts/remotetabs.rb. Note that it doesn’t attempt to do any error reporting, it just fails silently or times out if there’s a problem. You’ll know something went wrong, you just won’t know what. It’s mysterious, enjoy it.

Because I often run Webkit, and because Webkit demands that it be addressed separately from Safari, there’s a quick check in here to see which one is running at the time.

#!/usr/bin/ruby

def app_running?(app)
  not `ps ax|grep -i "#{app}.app"|grep -v grep`.empty?
end

def webkit_running?
  return false if `ps ax|grep -i "Safari.app"|grep -v grep`.empty?
  not `ps ax|grep -i "/Applications/Webkit.app"|grep -v grep`.empty?
end

if app_running?("Safari")
  browser = webkit_running? ? "Webkit" : "Safari"
  urllist = %x{osascript <<-APPLESCRIPT
               tell application "#{browser}"
               set _tabs to every tab of window 1
               set _urls to {}
               repeat with _tab in _tabs
               set end of _urls to URL of _tab
               end repeat
               set {astid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, " "}
               set output to _urls as text
               set AppleScript's text item delimiters to astid
               return output
               end tell
               APPLESCRIPT }.chomp
  puts urllist
end

getremotetabs.rb

This goes on the machine that's doing the "pulling." Save it as getremotetabs.rb in ~/scripts/ and run chmod a+x ~/scripts/getremotetabs.rb. You need to edit the remote_host variable in this script on each machine to match the hostname you set up in your ~/.ssh/config file for the 'other' Mac.

#!/usr/bin/ruby
# retrieves a list of urls from the front Safari window running on a remote machine

remote_host = 'air' # as set up in ~/.ssh/config with nick and keyless login

%x{ssh #{remote_host} ~/scripts/remotetabs.rb}.chomp.split(' ').each { |url|
  %x{osascript -e 'tell application "Safari" to open location "#{url}"'}
}

That's it. You can save an AppleScript with do shell script "/Users/username/scripts/getremotetabs.rb" anywhere you want to, or just call the script from the command line. Also, stop making fun of my OSD. I mean it.

Related posts:

1. Saving Safari browsing sessions to Evernote
2. Save Safari tabs to Instapaper
3. Geeklet: 1-minute average CPU load

Originally posted on BrettTerpstra.com at Duplicating Safari browsing sessions between Macs

I find it especially useful to be able to quickly encode and decode urls and strings when I’m testing online APIs out, but there are many times when I find I need this. I usually use a shell function or the very handy Hash Widget for Dashboard, but as a LaunchBar user, this is faster.

To use with LaunchBar, open the script in your Script Editor (instant-open links provided) and save it to ~/Library/Application Support/LaunchBar/Actions, creating the folder if it doesn’t already exist. Then, assuming you have Actions enabled in your indexing preferences, you can just type “urle” to get the action, then hit space to enter or paste the text to encode/decode. Alternatively, you can paste first or use Instant Send on a selection, then hit Tab and select the encode or decode action. To use elsewhere, such as in FastScripts, just save them as scripts in your ~/Library/Scripts folder. Using them outside of LaunchBar won’t be interactive; they will encode or decode your clipboard in place.

Side note: I decided to do the encoding/decoding in pure AppleScript, using functions I’ve mentioned previously from http://harvey.nu/. You can encode faster with Perl using a shell call, if you prefer. In a shell script for encoding, you’d use echo "string to encode"|perl -pe's/([^-_.~A-Za-z0-9])/sprintf("%%%02X", ord("$1"))/seg'. In AppleScript, that would look like set _res to do shell script "echo \"" & ASTextVar & "\"|perl -pe's/([^-_.~A-Za-z0-9])/sprintf(\"%%%02X\", ord(\"$1\"))/seg'", where ASTextVar is your string to encode.

The LaunchBar actions copy the resulting text to the clipboard, but you may prefer to have it passed back to LaunchBar for subsequent processing. There are commented lines in the scripts for doing so, just comment out the last line in the handle_string function and uncomment the line above it.

Here are the scripts/actions:

URL Encode

Open this script in your AppleScript editor: URLEncode.applescript

on handle_string(lbText)
	set _res to urlencode(lbText)
	-- to return the result to launchbar instead of copying it substitute
	-- the next line for the line after it (set the clipboard to _res)
	-- open location "x-launchbar:select?string=" & urlencode(_res)
	set the clipboard to _res
end handle_string
 
on run
	set the clipboard to urlencode(the clipboard as text)
end run
 
on urlencode(theText) -- http://harvey.nu/applescript_url_encode_routine.html
	set theTextEnc to ""
	repeat with eachChar in characters of theText
		set useChar to eachChar
		set eachCharNum to ASCII number of eachChar
		if eachCharNum = 32 then
			set useChar to "+"
		else if (eachCharNum &ne; 42) and (eachCharNum &ne; 95) and (eachCharNum < 45 or eachCharNum > 46) and (eachCharNum < 48 or eachCharNum > 57) and (eachCharNum < 65 or eachCharNum > 90) and (eachCharNum < 97 or eachCharNum > 122) then
			set firstDig to round (eachCharNum / 16) rounding down
			set secondDig to eachCharNum mod 16
			if firstDig > 9 then
				set aNum to firstDig + 55
				set firstDig to ASCII character aNum
			end if
			if secondDig > 9 then
				set aNum to secondDig + 55
				set secondDig to ASCII character aNum
			end if
			set numHex to ("%" & (firstDig as string) & (secondDig as string)) as string
			set useChar to numHex
		end if
		set theTextEnc to theTextEnc & useChar as string
	end repeat
	return theTextEnc
end urlencode

URL Decode

Open this script in your AppleScript editor: URLDecode.applescript

on handle_string(lbText)
	set _res to urldecode(lbText)
	-- to return the result to launchbar instead of copying it substitute
	-- the next line for the line after it (set the clipboard to _res)
	-- open location "x-launchbar:select?string="&urldecode(_res)
	set the clipboard to _res
end handle_string
 
on run
	set the clipboard to urldecode(the clipboard as text)
end run
 
on urldecode(theText) -- http://harvey.nu/applescript_url_decode_routine.html
	set sDst to ""
	set sHex to "0123456789ABCDEF"
	set i to 1
	repeat while i ≤ length of theText
		set c to character i of theText
		if c = "+" then
			set sDst to sDst & " "
		else if c = "%" then
			if i > ((length of theText) - 2) then
				display dialog ("Invalid URL Encoded string - missing hex char") buttons {"Crap..."} with icon stop
				return ""
			end if
			set iCVal1 to (offset of (character (i + 1) of theText) in sHex) - 1
			set iCVal2 to (offset of (character (i + 2) of theText) in sHex) - 1
			if iCVal1 = -1 or iCVal2 = -1 then
				display dialog ("Invalid URL Encoded string - not 2 hex chars after % sign") buttons {"Crap..."} with icon stop
				return ""
			end if
			set sDst to sDst & (ASCII character (iCVal1 * 16 + iCVal2))
			set i to i + 2
		else
			set sDst to sDst & c
		end if
		set i to i + 1
	end repeat
	return sDst
end urldecode

Related posts:

1. Save Safari tabs to Instapaper
2. Is your URL too short? Try our system, free!
3. TextMate drag command for Base64 encoding images

Originally posted on BrettTerpstra.com at LaunchBar actions for url encoding and decoding

Riffing on my AppleScript to toggle an app between foreground and hidden, and inspired by Daniel Jalkut’s script to toggle multiple Twitter apps, I wanted a way to do something similar with web browsers. I already have a great tool for intelligently detecting which browser I want to use: Choosy.

Choosy lets me set up “rules” and define behaviors which select the best option from my list of browsers, using the full list, just running browsers, or more specific lists based on source and type of the url I’m opening. I just needed to get it onto a hotkey.

Choosy, fortunately, has a url-handler for running different behaviors, which is detailed on the Choosy API page. All you need to do is run this AppleScript in your favorite hotkey-triggered script-launching app:

open location "x-choosy://open//"

That will trigger the Choosy popup HUD, which can be navigated by keyboard or mouse, where your full list of browsers shows up in your preferred order. Now, you’re hotkey will do exactly what the settings in Choosy tell it to do. You can have it automatically pick your favorite browser if none are running, or offer you a choice of preferred or all browsers. Personally, if no browser is running, I like the choice of all browsers. I also tell Choosy to automatically pick the running browser with the highest preference level in my settings if more than one are running.

This method works well for all the browsers I’ve tested, but has the annoying side effect of always opening a new tab in Chrome/Chromium. It’s not a big deal to me, but might be a deal breaker if Chrome is your primary browser.

I’m inspired to write a quick tool which takes a list of application names from AppleScript, pops up a Choosy-style HUD and returns the selected app name back to the script. A very simple CocoaDialog kind of thing, but better looking in this specific use case. It would make it possible to do this kind of trick with any type of app, and is basically Daniel’s script on steroids. It’s on my long list of projects to play with, we’ll see what happens.

Related posts:

1. LiveReload addendum
2. Quick Tip: Extracting Mac App Store reviews as text
3. Watch for file changes and refresh your browser automatically

Originally posted on BrettTerpstra.com at Quick Tip: Multi-browser hotkey with Choosy

From my hat full of stupid Mac tricks:

I use a lesser-known (and very old) program called Spark for defining most of the keyboard shortcuts on my system. I have a shortcut for every one of my most regularly-used applications, plus shortcuts for various AppleScripts, shell scripts, system functions, etc. I know there are more recent applications which do the same thing, but I’ve had everything set up in Spark for ages and it still works a treat. Seriously, if you want an application launcher, it’s worth checking out (and free). However, you can use this tip in any app which lets you assign a hotkey to an AppleScript (FastScripts, BetterTouchTool).

So, anyway, I’ve grown to like applications which have a system-wide hotkey that toggles them between foreground and hidden. It makes a lot of sense for certain applications which you check and then move on from. Sparrow, Twitter, etc. I wanted that functionality in more apps, so I run this as the AppleScript in Spark, replacing the app name with whatever I want to toggle.

set appName to "Mail"
 
set appID to bundle identifier of (info for (path to application appName))
tell application "System Events"
	if not (exists process appName) then
		tell application appID to activate
	else
		if frontmost of process appName then
			set visible of process appName to false
		else
			set frontmost of process appName to true
		end if
	end if
end tell

Sorry about the do shell script for launching the app. I’m really lazy about replacing more than one instance of a variable, and “tell application appName” doesn’t work, even with various “using terms from” attempts. Know how to fix that? Let me know. Thanks to D Curtis and Zettt in the comments, I’ve put together a more elegant script. It does the same thing without shelling out, and the syntax is cleaned up. Thanks guys!

One more update: after some testing, it looks like D Curtis’ first script below is much faster for some reason (I’m assuming that getting the “bundle identifier of (info for (path to application appName))” takes some extra resources). I recommend going with this one instead, but I’m leaving both up for reference:

set appName to "Mail"
set startIt to false
tell application "System Events"
	if not (exists process appName) then
		set startIt to true
	else if frontmost of process appName then
		set visible of process appName to false
	else
		set frontmost of process appName to true
	end if
end tell
if startIt then
	tell application appName to activate
end if

Related posts:

1. Quick Tip: Quickly clear stuck Growl notifications
2. Automating random giveaways, v1.0
3. A quick TextMate KeyBindings tip

Originally posted on BrettTerpstra.com at Quick tip: AppleScript application toggle

It’s a fairly simple AppleScript that requires nothing but Skype. It will make good use of Growl if you have it installed, but it’s only needed for visual feedback; the script will function fine without it. I use Spark to trigger it, but you can use any kind of launcher that can run AppleScripts. If Spark isn’t your cup of tea, definitely check out FastScripts. Ultimately, you just need to assign the following script to a hotkey…

The script

global _proc
global use_growl
 
tell application "System Events" to set _proc to name of processes as list
if _proc contains "GrowlHelperApp" then
	set use_growl to true
	my growlRegister()
else
	set use_growl to false
end if
 
if _proc contains "Skype" then
	tell application "Skype"
		set calls to send command "SEARCH ACTIVECALLS" script name "AnsweringScript"
		set callID to last word of calls
		if callID is not "CALLS" then
			set status to send command "GET CALL " & callID & " STATUS" script name "AnsweringScript"
			if last word of status is "RINGING" then
				send command "ALTER CALL " & callID & " ANSWER" script name "AnsweringScript"
				my growlNotify("SkypeAnswer", "Answering call")
				return
			else
				send command "ALTER CALL " & callID & " HANGUP" script name "AnsweringScript"
				my growlNotify("SkypeAnswer", "Hanging up")
			end if
		else
			my growlNotify("SkypeAnswer", "No call found to answer or hang up")
		end if
	end tell
else
	my growlNotify("SkypeAnswer", "Skype not detected")
end if
 
using terms from application "GrowlHelperApp"
	on growlRegister()
		tell application "GrowlHelperApp"
			register as application "SkypeAnswer" all notifications {"Alert"} default notifications {"Alert"} icon of application "Skype.app"
		end tell
	end growlRegister
 
	on growlNotify(grrTitle, grrDescription)
		if use_growl is true then
			tell application "GrowlHelperApp"
				notify with name "Alert" title grrTitle description grrDescription application name "SkypeAnswer"
			end tell
		end if
	end growlNotify
end using terms from

Open this script in your Script Editor

In an app like Spark, I can just paste the source into a new command and assign a hotkey. If you’re running a launcher that needs file input, just open the source in your AppleScript Editor and save it as an .scpt file, then point to that.

The script basically looks at current calls in Skype, and if a call is ringing or in progress, it takes the appropriate action (answers if it’s ringing, hangs up if it’s in progress). If no calls are happening, it will just exit (with a little whimper via Growl). Put it on an easy-to-hit keyboard shortcut and you’ll be able to grab your headset and answer a call faster than, well… faster than I’ve ever managed to without it.

Related posts:

1. Address Book search and Skype from the command line
2. Geeklet: Top RAM Processes
3. Duplicating Safari browsing sessions between Macs

Originally posted on BrettTerpstra.com at Answer Skype with a hotkey

Video preview

httpv://www.youtube.com/watch?v=KTcISVU4Nf4

YouTube Link…

Setting up your web server

To run it, you need to run your local web server as your own user. This is, of course, a major security risk and completely inadvisable if your local web server is open to outsiders in any way. Mine’s not, so I didn’t put too much time into figuring out a more secure way to do this. If you have any clues in that area, let me know and I’ll post them.

To run your local web server as a different user, you need to edit /etc/apache2/httpd.conf. You’ll need to edit it as root, so use sudo to launch your text editor of choice (e.g. sudo vi /etc/apache2/httpd.conf). If you, like me, just use TextMate’s mate command, you’ll be prompted for a password when you save.

Locate the lines:

User _www
Group _www

Change them to:

User yourusername
Group staff

You’ll also need to enable PHP, if you haven’t already. If you haven’t, locate the line that starts with:

#LoadModule php5_module

Just remove the hashmark at the beginning (#) to turn PHP on.

Now, at the command line, type sudo apachectl graceful to restart the server under the new user. If everything is in place, you’ll be able to run HomeControl without a hitch now. Turn on Web Sharing in System Preferences > Sharing to keep the web server running through reboots and logouts.

Installing HomeControl

Just download the zip file at the end of this post and unzip it into your ~/Sites folder. If you prefer to have it elsewhere, or have a custom folder set up for Apache, it will run just fine in any folder, as long as you can access it from a web browser on the local network.

Next, point your web browser to the folder. If you put the ‘homecontrol’ folder directly in ~/Sites, you should be able to reach it at the url http://computer_name.local/~Username/homecontrol. You need to know the name of the computer it’s on (set in System Preferences > Sharing, at the top), and your username on that system, substituting each in the appropriate place in the url.

Once you’ve loaded the page and tested it out, use the “+” icon at the bottom of Mobile Safari’s web browser to add an icon to your home screen which will take you directly there in the future, and will run the app full-screen.

Customizing HomeControl

Since I know not everybody who wants to try this out is going to be ready to hack into the jQuery and PHP, I made quite a few bits of the app modifiable with simple HTML edits. If you’re comfortable with that, you can change the list of applications and add iTunes features quite easily.

Application launcher

• Locate the div with the id “apps”
• Find the unordered list (<ul>) inside of it
• Edit or copy and edit existing lines by changing only the name of the application in the first span
• Use the exact displayed name of the application you want to control, and HomeControl will pass it to the PHP exec function

iTunes functions

• Locate the div with the id “itunes”
• Find the unordered list inside of it with the id “itunescmd”
• Add new features by copying an existing line and changing the rel attribute and the text of the link
  • The rel attribute passes the actual iTunes AppleScript command, which will be appended to a ‘tell application "iTunes" to’ line and passed to osascript
  • The text of the link is the title which will appear in the menu

iTunes EQ Presets

• Locate the div with the id “ituneseq”
• Find the unordered list inside of it
• Edit the text of the links in the list with the exact title of the preset you want to control
• Add or remove list items as desired

Startup screen and icon

• Edit homecontrolicon.png in the homecontrol folder to customize the app’s icon on the homescreen.
• Edit hc_startup.png in the homecontrol folder to customize the startup screen.
• If you’ve installed the web app, delete the icon and reinstall from Mobile Safari to see the new images.

Advanced customization

If you’re handy with the jQuery, the PHP and the HTML, you can do a lot with the examples in the code. It’s very much a proof-of-concept, and intended to be a jumping point for more experimentation, so have at it.

The app currently uses the jQTouch library, but mostly for the CSS. It has very few dependencies on the API, so it should be a relatively trivial matter to switch to a different library. It does rely quite heavily on jQuery, though.

The main PHP/osascript calls are in functions.php. All functions are called using jQuery’s $.get function, which makes Ajax calls to the functions.php file in the background and receives updates on completion.

Have fun, hopefully my horrible waste of time will be someone else’s inspiration…

Main Screen

Applications Screen

iTunes controls

Download

Related posts:

1. PromptDown for iOS: Mobile Markdown Teleprompter
2. The Mac and iOS mind mapping app extravaganza
3. Look, I made you a Markdown teleprompter

Originally posted on BrettTerpstra.com at HomeControl: Local Mac control for iPhone

For the record, I’m fully aware of the Option-Click shortcut to make all current notifications disappear, but thanks to all of the Twitter responses to that effect nonetheless. I really wanted a pure keyboard solution to handle this (I’m not alone). Usually, at least with apps that adhere to the Growl suggestion regarding stickiness, you only get sticky notifications when something goes wrong, and then you usually get more than one. I just wanted to be able to “poof” them away quickly and tend to whatever was causing them. I’m weird, I know.

After a lot of toying around, I decided to just go with a brute force method: quit the helper application and start it back up. It does the trick, and if you use AppleScript to handle the process, you can keep the bridge alive and experience no interruption in your Growl service. If you call the AppleScript with FastScripts, a launcher like Spark or even QuickSilver or LaunchBar, you can cause all sticky notifications to disappear with a keystroke of your choice.

Here’s the script:

tell application "GrowlHelperApp" to quit
delay 1
tell application "GrowlHelperApp" to activate

I found the 1 second delay necessary to let the process close out before trying to launch it again. If you run into issues with Growl not responding after running this script, you might try increasing that delay by a second or two. I also played around with using kill (grep/awk for the PID, kill the process, etc.), but the whole system stays much more stable this way.

There, my contribution to the keyboard-obsessed minority of OS X users.

Related posts:

1. Quick Tip: Quickly clear stuck Growl notifications
2. Quick tip: AppleScript application toggle
3. Answer Skype with a hotkey

Originally posted on BrettTerpstra.com at Clear sticky Growl notifications with a keyboard shortcut

Just add them to your TaskPaper Scripts folder (pull down the script menu and choose Open Scripts Folder). Then, assign them keyboard shortcuts using the Keyboard Preferences pane of System Preferences.

Put your cursor on a line with a task and run them. If there is no matching tag (@start or @due), one will be added for the current date. Once there’s a tag there, it will go forward and backwards days, depending on which script you’re running. Enjoy!

Related posts:

1. A few scripts for TaskPaper users
2. Automating TaskPaper to Day One logs
3. Natural language date conversion for TextMate

Originally posted on BrettTerpstra.com at Taskpaper Date Scripts

When I decided to fix this, the first issue was that when EverSave creates the Evernote note, it lets Evernote convert the list from HTML to Rich Text. Once it’s stored in Rich Text Format (RTF), manipulating it via any shell language, including AppleScript, becomes quite difficult. It’s not impossible, but I quickly decided it wasn’t a route I wanted to wander down. Here’s what I did do…

Saving tabs to Evernote

What I ended up doing was modifying what EverSave stored, and including the actual URL in the visible text of the note. It’s not the prettiest solution, but it’s the only way that this particular system will work. I did my best to minimize the visual presence of the URL using the rudimentary markup that Evernote actually pays attention to. The final product looks like this:

The actual layout is still fully controlled by the _template property in the first line, which is the only line that’s changed from the original script. I’m posting the whole thing again, with this minor revision, for convenience. With a little bit of HTML (remember to escape your double quotes), you can modify the template to look however you like. Just keep in mind that Evernote strips 90% of markup out when it creates the note from your HTML, so stick with basic tags. See the original EverSave post for a breakdown of the script.

Be sure to continue reading after the script to see how we handle the “restore” functionality.

property _template : "<li><strong><a href="%url">&uArr;</a> %name</strong> < <small>%url</small> >"
 
--search and replace function for template
on snr(tofind, toreplace, TheString)
	set ditd to text item delimiters
	set text item delimiters to tofind
	set textItems to text items of TheString
	set text item delimiters to toreplace
	if (class of TheString is string) then
		set res to textItems as string
	else -- if (class of TheString is Unicode text) then
		set res to textItems as Unicode text
	end if
	set text item delimiters to ditd
	return res
end snr
 
set prettyDate to do shell script "date '+%A, %B %d, %Y at %l:%M %p'"
set theTitle to "Bookmarks " & prettyDate
set urlList to "<ul>"
 
tell application "Safari"
	set tabList to every tab of front window
	repeat with aTab in tabList
		set aLink to _template
		set aLink to my snr("%name", name of aTab, aLink)
		set aLink to my snr("%url", URL of aTab, aLink)
		set urlList to urlList & aLink & return
	end repeat
end tell
set urlList to urlList & "</ul>"
 
tell application "Evernote"
	set theNote to create note with html urlList title theTitle notebook "Bookmarks"
end tell

I have this script saved as “EverSave.scpt” in my ~/Library/Scripts/Applications/Safari folder (create it if you don’t have it), and launch it using FastScripts with a Command-Shift-S shortcut. Safari doesn’t have anything bound to that key-combo, and it’s easy to remember (Save As in most programs).

Restoring tabs

This solution makes a few assumptions, but the script is easily customized to handle any differences in your setup. I went with a System Service (Snow Leopard) for the restore function, primarily because it allows me to act directly on selected text in Evernote. It’s a very simple Ruby script that parses the selected text for urls, and then opens any that it finds in sequential order using your default browser. There’s a commented out line if you want to always target Safari directly when opening them, which may be useful in some situations. I use Choosy, and have a rule that just directs all of these to Safari. If you have Safari set as your default browser, and that’s where you want to open your links, this will just work as is.

To set up the service:

1. Open Automator and select “Service” as the new file type.
2. On the right hand side, tell it that “Service receives selected” text in Evernote.app (choose Other… and select Evernote).
3. Find “Run Shell Script” in the list on the left and drag it into the area on the right.
4. Set the Shell dropdown to /usr/bin/ruby
5. Insert the following code, and feel free to modify
6. Save the result as “EverRestore”
7. Assign a shortcut key, if desired, in System Preferences > Keyboard > Keyboard Shortcuts > Services

Here’s the code for the service:

ARGF.each do |f|
    links = f.scan /< (https?://.*?) >/mi
    # The above scans specifically for the angle brackets in my template. 
    # If you remove those from the output of EverSave, be sure to update
    # the regular expression accordingly.
    if links.empty? then
        exit
    else
        links.each {|link| %x{osascript -e &#x27;open location "#{link[0]}"&#x27;}}
        # links.each {|link| %x{osascript -e &#x27;tell application "Safari" to open location "#{link[0]}"&#x27;} }
    end
end

The simple regular expression in line 2 does scan specifically for the angle brackets I used in the new EverSave template. That just relieves some complexity. If you want a regular expression that doesn’t require the angle brackets, try replacing line 2 with this:

links = f.scan /(https?://([^s",;]+)..{2,4}(/[^s",;!]+))/mi

Once it’s saved in Automator, it should be available when you select text in Evernote. If there are visible URLs in the selected text, running this Service will open them in tabs in Safari (or your default browser). You can selectively open certain urls by only selecting the lines that contain the ones you want to open. Non-contiguous selections will require a little text editing, of course.

Not as hard as it looks… really.

The explanation got a little long, and probably seems unnecessarily complex. The fact is, I can save a Safari browsing session with one key combo, edit, annotate and tag it (if I want to), then restore it later by highlighting and typing a new command combination. It’s actually quite convenient, and fairly bulletproof. I’d love to hear how you use it, or what you’re doing instead!

Related posts:

1. Antique Safari Reader hack update with Evernote goodness
2. Clippable to Evernote Snow Leopard Service
3. Save Safari tabs to Instapaper

Originally posted on BrettTerpstra.com at EverSave revisited, now with session restore!

I’ll be the first to admit that I get a little obsessed with projects that aren’t really going to improve my life all that much. Those projects can be fun to blog about, though, so I present you my brief obsession for this Sunday afternoon.

You may have noticed on this blog that some posts have header images, and some don’t, and that they get styled differently based on whether there’s an image or not. It pulls the header images from one of two places: the post thumbnail (which I can’t edit from MarsEdit) or the first image in the post content with a class of “headerimg”. As long as I’m blogging in MarsEdit (or TextMate for that matter), I’m stuck with the latter option. Because the whole header image deal is handled through PHP in my functions.php file, I can’t really preview how it’s going to look; rather, I get a header image stuck somewhere before, in or after my content. In TextMate, I have a little more “scriptability” at my disposal, and the previews I’ve created there are quite accurate. As far as I can tell, I can’t pre-process content before the template is generated, so I had to try something else… My solution, for now, is jQuery in the preview template. I load the jQuery library up top (inside the header) using Google’s Ajax API:

<script src="http://www.google.com/jsapi"></script>
<script>google.load("jquery", "1.4");</script>

Then, at the bottom, I just start polling for an image with the right class to show up. I know it’s brute force, but this isn’t exactly public-facing, and it doesn’t seem to cause any hiccups in my writing. I have this right before my closing body tag:

<script>
function fixHeader() {
    if ($('img.headerimg').attr('src') != undefined) {
        headerImg = $('img.headerimg').removeClass('headerimg').remove();
        postThumb = $('.postthumb:first');
        headerImg.prependTo(postThumb);
        postThumb.addClass('hasimage').removeClass('noimage');
    }
}
setInterval(fixHeader,2000);
</script>

I’m sharing this just to toss the idea out there, not because I think there’s anyone else with the exact same template setup as mine.

In addition to having Javascript at my disposal, MarsEdit is also AppleScript-able. I haven’t looked very far into that yet, but I did whip up a quick script for adding the “headerimg” class to my images (because I always forget which class I assigned for this):

tell application "MarsEdit"
    set selectionContents to selected text of document 1
    set {astid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "/>"}
    if selectionContents is not "" then
        set textToInsert to (text item 1 of selectionContents) & "class=\"headerimg\" />"
    end if
    set AppleScript's text item delimiters to astid
    set selected text of document 1 to textToInsert
end tell

That lets me just select an image (or pending upload tag) and run the script to add the necessary class.

Related posts:

1. MultiMarkdown in MarsEdit
2. Instapaper Beyond for Safari
3. Marked scripts: nvALT, Evernote, MarsEdit, Scrivener

Originally posted on BrettTerpstra.com at Fun with MarsEdit, part I

Unfortunately, one of my favorite apps right now, Delibar, doesn’t integrate with Spotlight or OpenMeta, despite the fact that it would be relatively easy to do. Delibar is an excellent (and sexy) menubar application for creating and searching Delicious (and Pinboard) bookmarks. A similar app, Pukka, pulls off the Spotlight part, but I still wanted OpenMeta tags that matched my Delicious tags for local searching.

I also use Tags.app for most of my tagging. OpenMeta tags allow you to group and classify files with simple tags, and provide a Spotlight-compatible way to search more intelligently. When you tag a website with Tags, it creates a webloc file in your metadata cache and applies the OpenMeta tags to it. I figured a similar approach would be feasible using AppleScript, and it seems to be working out great. Read on to see the script I’m using, and be sure to let me know if you improve on it!

What I’m doing is using curl with the Delicious API, and downloading everything that’s been bookmarked within the last hour. I’m running it with launchd every hour, so I don’t want to grab more than that every time it runs. It parses out the title, tags and url for the bookmark, saves it to a .webloc file, and tags it using Tags.app’s AppleScript commands. If you’re not running Tags, it could be modified pretty easily to work with the openmeta command line application.

I’m leaving the target folder up to the user, so when you define it in the CONFIG section, make sure it’s pointing to an existing folder. The only other config properties are your Delicious username and password (sent securely). As noted in the comments in the script, you can adjust the time/date it retrieves from in the first line after the CONFIG section.

The script is pretty well commented, so I won’t rewrite the whole thing here. Take a look, and then I’ll show you how I installed it.

-- CONFIG
property _user : "username" -- delicious username
property _pass : "password" -- delicious password
property targetFolder : "/Users/ttscoff/Library/Caches/Metadata/Delicious" -- POSIX path to existing folder
-- END CONFIG

set _date to do shell script "date -v-1d '+%Y-%m-%dT%H:%M:%SZ'"
-- returns a date 1 day ago in the format required by the twitter API.
-- you can adjust the date based on the frequency that you run the script
-- by editing the -v-1d part of the date command (-v-1H for 1 hour)
-- Note that the Delicious dates run on GMT, so you have to account for your time offset
-- For me, this means -v+4H if I want to go back one hour

set bookmarks to do shell script "curl https://" & _user & ":" & _pass & "@api.del.icio.us/v1/posts/all?fromdt=" & _date
-- gets the bookmarks starting with the date specified in _date

set _folder to POSIX file targetFolder as alias
-- turns the POSIX path in CONFIG into an AppleScript alias

tell application "System Events"
    set xmlDocument to make new XML data with data bookmarks
    -- create the XML object
    set {astid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, " "}
    -- store the current delimiter and set the new one to a space for breaking up the tags
    repeat with _post in XML elements of XML element 1 of xmlDocument
        set _url to value of XML attribute "href" of _post as string
        set _tags to text items of (value of XML attribute "tag" of _post as string)
        set end of _tags to "delicious"
        set _title to value of XML attribute "description" of _post as string
        try -- it fails on some files, the try block lets us keep moving if we hit a problem
            tell application "Finder" to set webloc to make new internet location file to _url at _folder with properties {name:_title}
            -- makes a .webloc file in our target folder
            tell application "Tags" to apply tags _tags to files {POSIX path of (webloc as string)}
            -- adds OpenMeta tags to our newly created file
        end try
    end repeat
    set AppleScript's text item delimiters to astid
    -- restore the delimiters
end tell

Open this script in your Script Editor

Installing

The first thing I did was make a version of the script that excluded the date parameter (fromdt) in the curl call in order to download my entire history and process it so I was up-to-date. This took a while, but didn’t seem to cause any problems. The Delicious API is pretty quick to throttle you, so download the whole bunch in one API call or you’ll be in trouble.

After editing the config options, I saved the file as an Application Bundle (see addendum below) in my own apps directory (~/Applications). It doesn’t matter where you put it (or what you name it), as long as you know the path to get there. Then I set up a launchd plist to run it every 3600 seconds (hour). I highly recommend Lingon for editing all things launchd. It will make sense when you get there.

Addendum

In reference to the install procedure above, I’ve actually had more luck saving it as a text file to a scripts folder and running it with osascript through launchd. Here’s my launchd plist, which you can edit and load through the “Expert” section of Lingon’s editor.

Also, as I just added into the code comments above, I didn’t originally account for the fact that Delicious dates are in GMT, and my offset is –5 right now, so I have to use –v+4H to get 1 hour back, not –v-1H.

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>Label</key>
    <string>org.brettterpstra.GetDelicious</string>
    <key>Nice</key>
    <integer>8</integer>
    <key>ProgramArguments</key>
    <array>
        <string>/usr/bin/osascript</string>
        <string>/Users/ttscoff/scripts/getdelicious</string>
    </array>
    <key>RunAtLoad</key>
    <true/>
    <key>StartInterval</key>
    <integer>3600</integer>
</dict>
</plist>

Areas for improvement:

• Currently errors out on some bookmarks for unknown reasons
• Could have a first-run setting to automatically download and tag ALL bookmarks
• Could set the created date of the webloc file based on the date of the bookmark from Delicious
• Could provide more feedback or logging

Related posts:

1. Delicious, Spotlight and OpenMeta tags, revisited
2. Mirror your Pinboard bookmarks with OpenMeta tags
3. Natural Language Date Service update

Originally posted on BrettTerpstra.com at Delicious bookmarks and OpenMeta tags